# Maintainer: Alexey Pavlov <alexpux@gmail.com>

_realname=beaker
pkgbase="python-${_realname}"
pkgname=("python-${_realname}")
pkgver=1.12.1
pkgrel=1
pkgdesc="Caching and sessions WSGI middleware for use with web applications and stand-alone Python scripts and applications"
arch=('any')
license=('PSF')
url="https://beaker.readthedocs.org"
depends=("python")
makedepends=(
  "python-setuptools"
  "python-wheel"
  "python-build"
  "python-installer"
)
provides=("python3-${_realname}")
conflicts=("python3-${_realname}")
replaces=("python3-${_realname}")
source=("${_realname}-${pkgver}.tar.gz"::https://github.com/bbangert/beaker/archive/${pkgver}.tar.gz)
sha256sums=('135c41ce48a7f994c15abe050949e6ce70f3e164f0dc81ceb56c4d9e3106b9f2')

prepare() {
  cd "${srcdir}/${_realname}-${pkgver}"
}

build() {
  cd "${srcdir}/${_realname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${srcdir}/${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl
  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/python-beaker/LICENSE"
}
