# Maintainer: J. Peter Mugaas <jpmugaas@suddenlink.net>

_realname=pbr
pkgbase=python-${_realname}
pkgname=(python-${_realname})
pkgver=6.0.0
pkgrel=1
pkgdesc="Python Build Reasonableness"
arch=('any')
url='https://pypi.python.org/pypi/pbr'
license=('spdx:Apache-2.0')
depends=('python-setuptools')
makedepends=(
  "python-wheel"
  "python-build"
  "python-installer"
)
provides=("python3-${_realname}")
conflicts=("python3-${_realname}")
replaces=("python3-${_realname}")
source=("${pkgbase}-${pkgver}.tar.gz::https://github.com/openstack-dev/pbr/archive/${pkgver}.tar.gz")
sha256sums=('f546cc6fd22b76d10beda133fc741ac404266c0e5d2da42c89dc3883235c54f3')

prepare() {
  cd "${srcdir}/${_realname}-${pkgver}"
  export PBR_VERSION=${pkgver}
}

build() {
  cd "${srcdir}/${_realname}-${pkgver}"

  python -m build --wheel --skip-dependency-check --no-isolation
}

package() {
  cd "${srcdir}/${_realname}-${pkgver}"

  python -m installer --destdir="${pkgdir}" dist/*.whl

  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
