@ECHO OFF
REM makepk gf_font base_resolution real_resolution
IF %1.==. GOTO USAGE
IF %2.==. GOTO USAGE
IF %3.==. GOTO USAGE
REM set up directories by analyzing base_resolution
IF .%2.==.101. SET FONTDIR=DVI101
IF .%2.==.300. SET FONTDIR=DVILW300
IF .%2.==.216. SET FONTDIR=DVI216
IF .%2.==.180. SET FONTDIR=DVI180
IF .%2.==.360. SET FONTDIR=DVI360
IF NOT %FONTDIR%.==. GOTO WEITER
ECHO.
ECHO Ich kenne fuer %2 keinen Zeichensatzordner.
ECHO Bitten Sie Ihren TeX Guru, den MAKEPK Batch zu erweitern!
GOTO USAGE
:WEITER
SET @TPATH@=%PATH%
PATH %EMTEXDRV%:\EMTEX;%PATH%
IF EXIST %EMTEXDRV%:\PDFONTS\%FONTDIR%\*.* GOTO FINE
ECHO Ich erzeuge einen neuen Zeichensatzordner %FONTDIR%
MKDIR %EMTEXDRV%:\PDFONTS\%FONTDIR%
ECHO "Do not delete this file!" >%EMTEXDRV%:\PDFONTS\%FONTDIR%\READ.ME
ECHO "It is needed for automatic font generation." >>%EMTEXDRV%:\PDFONTS\%FONTDIR%\READ.ME
:FINE
IF EXIST %EMTEXDRV%:\PDFONTS\%FONTDIR%\%3\*.* GOTO FINEFINE
ECHO Ich erzeuge einen neuen Ordner fuer Aufloesung %3
MKDIR %EMTEXDRV%:\PDFONTS\%FONTDIR%\%3
:FINEFINE
%EMTEXDRV%:\EMTEX\GFTOPK %1.%3gf %EMTEXDRV%:\PDFONTS\%FONTDIR%\%3\%1.PK
PATH %@TPATH@%
SET @TPATH@=
COPY %1.TFM %EMTEXDRV%:\EMTEX\TFM >NUL
DEL %1.TFM
DEL %1.%3GF
DEL %1.LOG
GOTO EXIT
:USAGE
ECHO.
ECHO Parameterfehler: MAKEPK zeichensatz basis_aufloesung(dpi) aufloesung(dpi)
ECHO.
:EXIT
SET FONTDIR=